Odgovori 
Dodatak sloval ne radi

Naravno da hoće, nadam se i nekom drugom ! Smile
Nije baš naj elegantnije rešenje za izradu računa i predračuna, ali radi.
Najlepše hvala.
Citiraj ovu poruku u odgovoru

Lepo rešenje al evo sve u jednoj formuli kome treba. Iznos računa je u polju A10,pa ga zamenite željenim poljem.
U ovom slučaju ne morate imati dodatne sheet-ove.
Kod:
=(NUMBERTEXT(TRUNC(A10);"sr"))&" "&IF(AND(MOD(TRUNC(A10);10)=1; MOD(TRUNC(A10);100)<>11); "динар";"динара")&" и " & FLOOR(A10 - TRUNC(A10);0,01)*100 & "/100"

Citiraj ovu poruku u odgovoru

Evo male ispravke zbog bug-a oko floating point (verovatno) jer iako je broj na dve decimale, prikazuje ga sa više. Ono što morate da obezbedite je da broj bude stvarno sa 2 decimale, odnosno zaokružen a ne samo formatiran.

Kod:
=(NUMBERTEXT(TRUNC(L37);"sr"))&" "&IF(AND(MOD(TRUNC(L37);10)=1; MOD(TRUNC(L37);100)<>11); "динар";"динара")&" и " & TEXT((L37 - FLOOR(ROUND(L37;2);1;)) * 100;"##") & "/100"

Citiraj ovu poruku u odgovoru

Kada je iznos npr. 11 dinara, dobija se "jedanaest dinara i /100". Mislim da bi trebalo "jedanaest dinara i 00/100".

Ko koristi AOO ova varijanta će raditi (otklonjen je znak ";" koji je bio deo Floor funkcije, iza broja jedan):
=(NUMBERTEXT(TRUNC(L37);"sr"))&" "&IF(AND(MOD(TRUNC(L37);10)=1; MOD(TRUNC(L37);100)<>11); "динар";"динара")&" и " & TEXT((L37 - FLOOR(ROUND(L37;2);1)) * 100;"##") & "/100"

Apache OpenOffice 4.0.1 Win
Citiraj ovu poruku u odgovoru

Evo malo preuređene funkcije. Sada se uvek pojavljuju oznake za pare. Ako je iznos 5,00 biće "pet dinara i 00/100". Takođe je dodato da se očitavaju i negativni brojevi koji se mogu dobiti kod nivelacija. Ako je iznos npr. -500,00, očitaće ga kao da je pozitivan broj.


="Словима: "&(NUMBERTEXT(TRUNC(ABS(A10));"sr"))&" "&IF(AND(MOD(TRUNC(A10);10)=1; MOD(TRUNC(A10);100)<>11); "динар";"динара")&" и " & RIGHT(FIXED(ROUND(A10;2));2) & "/100"

Apache OpenOffice 4.0.1 Win
Citiraj ovu poruku u odgovoru
Odgovori 




Kontakt | otvorenidokument.com | Povratak na vrh | Povratak na sadržaj | RSS