Forum LibreOffice i OpenOffice korisnika

**Vladislav Stevanović**

Kojim pristupom se može proveriti da li je dostupan na lageru određen proizvod čiji parametri se ubacuju u A1 i D1 ćeliji, a u tabeli je plavom bojom naznačeno koji proizvodi su dostupni. Kako povezati tu tabelu sa ćelijom A1 i D1 da bi dobili u žuto obojenoj ćeliji odgovor "Dostupno" ili "Nije dostupno"?
Unapred hvala na idejama.

***Goran Rakić***

Može da se koristi sledeća formula:

Kod:

=IF(

    OFFSET(H2;

        IFERROR(MATCH(A1;H3:H19;-1);0);

        IFERROR(MATCH(D1;I2:P2;1);0)

    )="x"; 

   "RASOLOŽIVO"; "NIJE RASPOLOŽIVO"

)

Kao što vidite, najpre funkcijom OFFSET() tražimo odgovarajući red i kolonu funkcijama MATCH() prema onome što je uneto u A1 i D1.

Zatim sam umesto da su samo "obojene plavo" u ćelije koje su raspoložive uneo nevidljivo "x" (istom plavom bojom). Sada funkcijom IF možemo da proverimo da li ćelija ima "x" ili ne, odnosno da li je "raspoloživo" ili "nije raspoloživo".

IFERROR() koristimo za slučaj da MATCH() ne pronađe traženu vrednost, u tom slučaju sa proverava ćelija H2 koja nema "x". To znači ako se ne pronađe tražena vrednost, vratićemo "nije raspoloživo".

**Vladislav Stevanović**

Gorane, hvala. Ovo radi u LO-u. Problem za mene je što AOO koji koristim još ne podržava IFERROR funkciju. Da li postoji mogućnost da se u kombinaciji drugih funkcija nadomesti taj nedostatak?
Srdačan pozdrav,
Vlatko

***Goran Rakić***

Može:

Kod:

IF(

     ISERROR( izraz );

     0;

     izraz

)

Ovaj kod je ekvivalent funkciji IFERROR(), jedino izraz (a gore je to "MATCH(A1;H3:H19;-1)") morate da zapišete dva puta.

**Vladislav Stevanović**

Da, uradio sam i dobio ovo:

Kod:

=IF(

    OFFSET(H2;

        IF(

     ISERROR(MATCH(A1;H3:H19;-1));

     0;

     MATCH(A1;H3:H19;-1)

) ;

        IF(

     ISERROR(MATCH(D1;I2:P2;1));

     0;

     MATCH(D1;I2:P2;1)

) 

    )="x"; 

   "RASOLOŽIVO"; "NIJE RASPOLOŽIVO"

)

ali ne radi mi kako sam očekivao.

Opss. Izgleda da grešim. Radi se o tome da su ćelije bile formatirane kao tekst. Dolazilo je lakše do greške, bilo da je korišćena engleska tastatura (umesto zareza je kucana tačka, ili nešto drugo), pa sam promenio formatiranje ćelija na brojeve. Sada je sve u redu. Još jednom, hvala.